Luigit
repositories / dotfiles

dotfiles

bugabingas dorkfiles

owned by admin

quickshell/nuguland/features/osd/fixtures/load.qml

Raw
import QtQuick
import QtQuick.Window
import Quickshell
import "../../.." as N
import "../../../features/osd" as OsdFeature

// `just load-test osd`: the registry overlay entry's own panel, bound to the
// real OSD service (pure state plus a timer, nothing native to double). One
// meter event must map the entry and lay out the card. No compositor, input,
// or pixels.
ShellRoot {
    id: root

    readonly property N.FeatureEntry feature: registry.overlay("osd")

    function finish(): void {
        const panel = loader.item as OsdFeature.OsdPanel;
        if (panel && root.feature.kind === "overlay" && root.feature.overlayShown && panel.implicitHeight > 64) {
            console.log("load osd: PASS");
            Qt.quit();
        }
    }

    N.Theme {
        id: nuguTheme
    }

    N.Registry {
        id: registry

        theme: nuguTheme
    }

    // Plain Window: Quickshell windows set input masks the offscreen platform rejects.
    Window {
        width: 316
        height: 160
        visible: true
        color: "transparent"

        Loader {
            id: loader

            anchors.fill: parent
            sourceComponent: root.feature ? root.feature.panel : null
        }
    }

    Component.onCompleted: registry.osd.trigger("volume", "72")

    Timer {
        interval: 25
        running: true
        repeat: true
        onTriggered: root.finish()
    }

    Timer {
        interval: 5000
        running: true
        onTriggered: {
            console.error("ERROR load osd: registry overlay panel never rendered a triggered event");
            Qt.quit();
        }
    }
}