bugabinga.net

# https://just.systems

set positional-arguments

alias nugu := _nugu

default:
    @just --list

# format and validate all configuration, or selected paths; prefix with read for no mutation
check *args:
    @scripts/local/check.sh "$@"

# run an OpenTofu operation: init, migrate, state, unlock, test, or output
tofu +args:
    @just --dotenv-path .env _tofu "$@"

_tofu +args:
    @scripts/local/tofu.sh "$@"

# create and review the saved OpenTofu plan
plan:
    @just --dotenv-path .env _tofu plan

# apply only the previously reviewed saved OpenTofu plan
apply:
    @just --dotenv-path .env _tofu apply

# generate assets or credentials: nugu, zot-user, basic-auth-user
generate +args:
    @scripts/local/generate.sh "$@"

_nugu:
    @scripts/local/generate.sh nugu

# run verification: infra, ipv6, sites, luci-e2e, luci-mutation, go, go-race, go-staticcheck, go-vuln, luci-bench, luci-benchstat
verify +args:
    @scripts/local/verify.sh "$@"

# run Luigit Rust checks: fmt, clippy, test
rust +args:
    @scripts/local/rust.sh "$@"

# deploy an artifact: luci-image or quest-log-image
deploy +args:
    @scripts/local/deploy.sh "$@"

# verify required tools; pass hooks to install repository hooks afterward
setup *args:
    @scripts/local/setup.sh "$@"